Emulace 6502 na Z80

Nazdar spectristi,

tete si dal slo diskmagaznu Restore a asi se divte, co e to m spolenho s tޒregistrovm procesorem 6502.
Nkdy roku 2004 jsem si vytvoil emultor Apple I pro ZX Spectrum.
Soust tohoto emultoru byl i disassembler a jednoduch assembler kdu pro procesor 6502.
O nm jsem napsal sri lnk u roku 2005.
Ale co samotn jdro emultoru?
Kd a zdrojk je oteven.
Pokud jej pochopte tak, e jej dokete pout ve vlastnm programu, uite tak, nic a nikdo vm v tom nebrn.

Skoro dvacet let ale trvalo dostat zdrojk ze starho notebooku.
Byl psn v ruskm assembleru ZXASM 3.0 pro Betadisk v emultoru X128 pod MS DOSem.

Te tu mme zdrojk v lidsky iteln podob, ovem, jak bylo mm zvykem z Promethea, nehޒ moc komenti a bylo by asi t ho pochopit.
Opatuji jej tedy vysvtlujcm textem.

Vtina kdu je nezvisl na hardware, emultor je tedy pomrn snadno penositeln na rzn Z80 platformy.
Na hardware zvisl je manaer jednotlivch emulovanch procesorovch cykl.
Toti pot, co zavol proveden jednoho procesorovho cyklu (CALL INSTRUCTION), te klvesnici, ske do menu, emuluje stisk hardwarovch tlatek - RESET a u Apple I t hardwarov smazn obrazovkxy.
T pޒpadn vol vypis obsahu registr a obsluhuje jeho zapnut nebo vypnut.
Vol extern rutinu INKEY, kter te klvesnici, a rutiny v modulu MONITOR, kter obsahuje hlavn menu emultoru s u zmnnm assemblerem a disassemblerem.
Obsahuje i rutinu MONITOR pro vpis obsahu registr.
Ta zan pepisovac instrukc - bu RET, kdy se vpis registr neprovede, nebo NOP, kdy se rutina pro vpis vykon.


                      
 6502 Virtual Machine 
                      

 
; CYCLE MANAGER * HW dependent
; INSTR. CYCLE  * HW independent
; 6502 CORE     * HW independent
; REGISTERS     * HW independent


 6502 CYCLE MANAGER 

;** HW dependent **
;uses keyboard
;uses monitor

cycle call instruction

     call inkey
     or a:jp z,nomkey
     cp 8:jr z,oneinstr
     cp 9:jr z,cycleinstr
     cp 15:jr z,hwclrscr
     cp 7:jp z,reset
     cp 4:jr z,monitoroff
     cp 5:jr z,monitoron
     cp 10:jp z,menudown
     cp 11:jp z,menuup
     cp 6:call z,caps
nomkey
retmonitor call monitor
     ld a,(iy+48):ld (23232),a    ;CAPS
     jp cycle

monitoron xor a:ld (monitor),a
      ld hl,23264:ld de,23265
      ld (hl),%001111:ld bc,31:ldir
      jr retmonitor
monitoroff ld a,201:ld (monitor),a
      ld hl,23264:ld de,23265
      ld (hl),%001001:ld bc,31:ldir
      jr retmonitor
hwclrscr res 5,(iy+1)
         call clearscreen
         jr retmonitor

oneinstr ld a,201:ld (instruction),a
         res 5,(iy+1)
         call step
         jp monitoron
cycleinstr xor a:ld (instruction),a
           res 5,(iy+1)
           jp retmonitor

Nyn jsme v sti, kter byla sama o sob hardwarov nezvisl, ale vol dv extern hardwarov zvisl rutiny, kter jet podrobnji popu.
Navc u jsem do n zaal ne pln systmov pidvat rutiny sice na hardware nezvisl, ale specifick pro dan emulovan pota - na adresch C170, C18D a C163 jsou toti vstupy do rutin pro obsluhu magnetofonu na Apple I.
Tedy, pokud emulovan registr PC obsahuje hodnoty C170, C18D nebo C163, provedou se skoky na rutiny TAPEW pro zpis, TAPER pro ten a TAPEEOL je vstupn bod.

Prvn instrukce obsluhy instruknho cyklu je NOP nebo RET.
Tuto instrukci mn ji manaer procesorovch cykl, kter jsme si u popsali.
Pokud je zde NOP, emulovan procesorov cykly se normln vykonvaj.
Pokud je zde RET, neprovd se nic, emulovan procesor stoj a manaer tak jen te ovldac klvesy.
Volnm od adresy STEP se vykon emulace jedn instrukce vdy.

V provn sti je dekdovn instrukce - pokud nen vykonvn kd z ROM kazetovho interface, nate se z adresy uren emulovanm registrem PC kd instrukce a v tabulce TABLE se vyhled adresa, na kter je rutina pro vykonn instrukce s natenm kdem.



 6502 INSTR. CYCLE 

;** HW independent **
;uses memory manager

instruction nop        ;RET disables run
step        ld a,(regpc+1):cp #c1
            call z,tapepoints
            call step1
            jp param   ;inc PC
step1  ld hl,(regpc):call loada
       ld de,table:ld h,0:ld l,a
       add hl,hl
       add hl,de
       ld  a,(hl):ld (jump+1),a
       inc hl:ld a,(hl):ld (jump+2),a
jump   jp 0

tapepoints ld a,(regpc)
           cp #70:jp z,tapew
           cp #8d:jp z,taper
           cp #63:jp z,tapeeol
           ret

Je naase zmnit se o rutinch LOADA a STOREA, kter vlastn slou emulovanmu procesoru ke komunikaci s okolnm svtem.
Ob jsou hardwarov zvisl a nejsou soust tohoto vpisu.
O co jde?
Jde o to, e obsluhuj virtuln adresov prostor emulovanho procesoru 6502.
Ten nem addlen porty a pam, vlastn vecny periferie jsou "mapovan do pamti" ve spolenm 64 KiO prostoru.

Zpracovvan adresa je v HL registru Z80, zapisovan nebo naten hodnota v A akumultoru Z80.
LOADA a STOREA mohou bt, podle sloitosti hardware emulovanho potae, pomrn komplexn.
Zajiuj tedy peklad adres 6502 na adresy Z80, pޒpadn strnkovn pamti v pޒpad ZX Spectra 128 (napޒklad mj emultor Apple I na ZX 48 emuluje 16 KiO RAM, zatmco na ZX 128 pomoc strnkovn 32 KiO RAM).
A stejn tak zajiuj styk s periferiemi (ten klvesnice, obsluha registr rznch ip - grafickch, zvukovch, ...).
Protoe Apple I nem VideoRAM, ale komunikace se zobrazovaem probh pes port terminlu, neeil mj emultor emulaci grafickho ipu ani vytn VideoRAM, jen zpis na terminl.

A te pichz samotn hadwarov nezvisl jdro, samo vyuv jen rutiny LOADA a STOREA.

"Ilegln" instrukce i NOP nedlaj nic, ani ekn - potal jsem s tm, e sama emulace bude natolik pomal, e nco takovho nebude poteba.

Nvt vtinou srozumiteln naznauj, jak instrukce se v dan rutin zpracovaj.
Voln rutin PARAM8 a PARAM16 zpsob naten osmibitovho nebo 16bitovho parametru instrukce.

Zanme instrukcemi plnn registr.


   6502 CORE   

ilg
noop ret

tax ld a,(rega)
t_x ld (regx),a
    ld (data),a
    call negative
    jp zeroa

tay ld a,(rega)
t_y ld (regy),a
    ld (data),a
    call negative
    jp zeroa

txa ld a,(regx)
t_a ld (rega),a
    ld (data),a
    call negative
    jp zeroa

tya ld a,(regy)
    jp t_a

tsx ld a,(regs)
    jp t_x

txs ld a,(regx)
    ld (regs),a
    ret

ldak call param8
     jp t_a

ldam call param16
     call loada
     jp t_a

ldamx call param16
      call addx16
      call loada
      jp t_a
ldamy call param16
      call addy16
      call loada
      jp t_a

ldaz call param8
     ld l,a:ld h,0:call loada
     jp t_a

ldazx call param8
      ld l,a:ld h,0
      call addx8
      call loada
      jp t_a

ldaix call param8
      ld l,a:ld h,0
      call addx8
      call paramind
      call loada
      jp t_a

ldaiy call param8
      ld l,a:ld h,0
      call paramind
      call addy16
      call loada
      jp t_a

ldxk call param8
     jp t_x

ldxm call param16
     call loada
     jp t_x

ldxmy call param16
      call addy16
      call loada
      jp t_x

ldxz call param8
     ld l,a:ld h,0:call loada
     jp t_x

ldxzy call param8
      ld l,a:ld h,0
      call addy8
      call loada
      jp t_x

ldyk call param8
     jp t_y

ldym call param16
     call loada
     jp t_y

ldymx call param16
      call addx16
      call loada
      jp t_y

ldyz call param8
     ld l,a:ld h,0:call loada
     jp t_y

ldyzx call param8
      ld l,a:ld h,0
      call addx8
      call loada
      jp t_y

stam call param16
     ld a,(rega)
     call storea
     ret

stamx call param16
      call addx16
      ld a,(rega)
      call storea
      ret

stamy call param16
      call addy16
      ld a,(rega)
      call storea
      ret

staz call param8
     ld l,a:ld h,0:ld a,(rega)
     call storea
     ret

stazx call param8
      ld l,a:ld h,0
      call addx8
      ld a,(rega)
      call storea
      ret

staix call param8
      ld l,a:ld h,0
      call addx8
      call paramind
      ld a,(rega)
      call storea
      ret

staiy call param8
      ld l,a:ld h,0
      call paramind
      call addy16
      ld a,(rega)
      call storea
      ret

stxm call param16
     ld a,(regx)
     call storea
     ret

stxz call param8
     ld l,a:ld h,0:ld a,(regx)
     call storea
     ret

stxzy call param8
      ld l,a:ld h,0
      call addy8
      ld a,(regx)
      call storea
      ret

stym call param16
     ld a,(regy)
     call storea
     ret

styz call param8
     ld l,a:ld h,0:ld a,(regy)
     call storea
     ret

styzx call param8
      ld l,a:ld h,0
      call addx8
      ld a,(regy)
      call storea
      ret

pha ld a,(rega)
    ld hl,(regsp)
    ld (data),a
    call storea
    call pushni
    call negativea:jp zeroa

php ld a,(regp)
    ld hl,(regsp)
    call storea
    call pushni
    ret

pla call popni
    ld hl,(regsp)
    call loada
    ld (rega),a
    ld (data),a
    call negativea:jp zeroa

plp call popni
    ld hl,(regsp)
    call loada
    ld (regp),a
    ret

pushni ld a,(regs):dec a
       ld (regs),a:ret
popni ld a,(regs):inc a
      ld (regs),a:ret

jmpk call param16
     dec hl
     ld (regpc),hl
     ret

jmpm call param16
     push hl
     call loada
     ld (adr),a
     pop hl
     inc hl
     call loada
     ld (adr+1),a
     ld hl,(adr)
     dec hl
     ld (regpc),hl
     ret

jsr call param16
    ld a,(regpc+1)
    ld hl,(regsp)
    call storea
    call pushni
    ld a,(regpc)
    ld hl,(regsp)
    call storea
    call pushni
    ld hl,(adr)
    dec hl
    ld (regpc),hl
    ret

rts call popni
    ld hl,(regsp)
    call loada
    ld (regpc),a
    call popni
    ld hl,(regsp)
    call loada
    ld (regpc+1),a
    ret

brk call param
    ld a,(regpc+1)
    ld hl,(regsp)
    call storea
    call pushni
    ld a,(regpc)
    ld hl,(regsp)
    call storea
    call pushni
    call php
    ld hl,#fffe
    call loada
    ld (adr),a
    ld hl,#ffff
    call loada
    ld (adr+1),a
    ld hl,(adr)
    ld (regpc),hl
    call setb
    ret

rti call plp
    jp rts

beq call param8
    ld   (relparam),a
    call tstz
    ret z
relcom ld a,(relparam)
    bit 7,a
    jr nz,relback
relfwd ld hl,(regpc)
       ld e,a
       ld d,0
       add hl,de
       ld (regpc),hl
       ret
relback xor #ff
        ld hl,(regpc)
        ld e,a
        ld d,0
        scf
        sbc hl,de
        ld (regpc),hl
        ret
relparam nop

bne call param8
    ld (relparam),a
    call tstz
    ret nz
    jp relcom

bmi call param8
    ld (relparam),a
    call tstn
    ret z
    jp relcom

bpl call param8
    ld (relparam),a
    call tstn
    ret nz
    jp relcom

bcs call param8
    ld (relparam),a
    call tstc
    ret z
    jp relcom

bcc call param8
    ld (relparam),a
    call tstc
    ret nz
    jp relcom

bvs call param8
    ld (relparam),a
    call tstv
    ret z
    jp relcom

bvc call param8
    ld (relparam),a
    call tstv
    ret nz
    jp relcom

adck call param8
adccom ld (data),a
     call tstd
     jp z,adcnd
     ld a,39:ld (adcdec),a ;DAA
adcnd call tstc
     ld a,(data)
     ld b,a
     jr z,adcnocarry
     scf:jp adcc
adcnocarry scf:ccf
adcc       ld a,(rega)
           adc a,b
adcdec     nop
           ld  (rega),a
           push af
           call carry
           pop af
           call flow
     ld a,(rega):call negative
     ld a,(rega):call zero
     xor a:ld (adcdec),a:ret

adcm call param16
     call loada
     jp adccom
adcmx call param16
      call addx16
      call loada
      jp adccom
adcmy call param16
      call addy16
      call loada
      jp adccom
adcz call param8
     ld l,a:ld h,0:call loada
     jp adccom
adczx call param8
      ld l,a:ld h,0
      call addx8
      call loada
      jp adccom
adcix call param8
      ld l,a:ld h,0
      call addx8
      call paramind
      call loada
      jp adccom
adciy call param8
      ld l,a:ld h,0
      call paramind
      call addy16
      call loada
      jp adccom

sbck call param8
sbccom ld (data),a
       call tstd
       jp z,sbcnd
       ld a,39:ld (sbcdec),a ;DAA
sbcnd  ld a,(data):ld b,a
       call tstc
       jr z,sbcnocarry
       scf:ccf:jp sbcc ;~CARRY
sbcnocarry scf         ;~CARRY
sbcc   ld a,(rega)
       sbc a,b
sbcdec nop
       push af
       ld  (rega),a
       ccf
       call carry
       pop af
       call flow
     ld a,(rega):call negative
     ld a,(rega):call zero
     xor a:ld (sbcdec),a:ret

sbcm call param16
     call loada
     jp sbccom
sbcmx call param16
      call addx16
      call loada
      jp sbccom
sbcmy call param16
      call addy16
      call loada
      jp sbccom
sbcz call param8
     ld l,a:ld h,0:call loada
     jp sbccom
sbczx call param8
      ld l,a:ld h,0
      call addx8
      call loada
      jp sbccom
sbcix call param8
      ld l,a:ld h,0
      call addx8
      call paramind
      call loada
      jp sbccom
sbciy call param8
      ld l,a:ld h,0
      call paramind
      call addy16
      call loada
      jp sbccom

incz call param8
     ld h,0:ld l,a
incc ld (adr),hl
     call loada
     inc a
     ld (data),a
     ld hl,(adr)
     call storea
     call negativea
     jp zeroa
inczx call param8
      ld h,0:ld l,a
      call addx8
      jp incc
incm call param16
     jp incc
incmx call param16
      call addx16
      jp incc

inx ld a,(regx)
    inc a
    ld (regx),a
    ld (data),a
    call negative
    jp zeroa

iny ld a,(regy)
    inc a
    ld (regy),a
    ld (data),a
    call negative
    jp zeroa

decz call param8
     ld h,0:ld l,a
decc ld (adr),hl
     call loada
     dec a
     ld (data),a
     ld hl,(adr)
     call storea
     call negativea
     jp zeroa
deczx call param8
      ld h,0:ld l,a
      call addx8
      jp decc
decm call param16
     jp decc
decmx call param16
      call addx16
      jp decc

dex ld a,(regx)
    dec a
    ld (regx),a
    ld (data),a
    call negative
    jp zeroa

dey ld a,(regy)
    dec a
    ld (regy),a
    ld (data),a
    call negative
    jp zeroa

asla ld a,(rega)
     sla a
     ld (data),a
     call carry
     ld a,(data)
     ld (rega),a
     call negative
     jp zeroa

aslz call param8
     ld h,0:ld l,a
     ld (adr),hl
     call loada
     sla a
     ld (data),a
     call carry
     ld a,(data)
     ld hl,(adr)
     call storea
     call negativea
     jp zeroa

aslzx call param8
     ld h,0:ld l,a
     call addx8
     ld (adr),hl
     call loada
     sla a
     ld (data),a
     call carry
     ld a,(data)
     ld hl,(adr)
     call storea
     call negativea
     jp zeroa

aslm call param16
     ld (adr),hl
     call loada
     sla a
     ld (data),a
     call carry
     ld a,(data)
     ld hl,(adr)
     call storea
     call negativea
     jp zeroa

aslmx call param16
      call addx16
      ld (adr),hl
      call loada
      sla a
      ld (data),a
      call carry
      ld a,(data)
      ld hl,(adr)
      call storea
      call negativea
      jp zeroa

lsra ld a,(rega)
     srl a
     ld (data),a
     call carry
     ld a,(data)
     ld (rega),a
     call negative
     jp zeroa

lsrz call param8
     ld h,0:ld l,a
     ld (adr),hl
     call loada
     srl a
     ld (data),a
     call carry
     ld a,(data)
     ld hl,(adr)
     call storea
     call negativea
     jp zeroa

lsrzx call param8
     ld h,0:ld l,a
     call addx8
     ld (adr),hl
     call loada
     srl a
     ld (data),a
     call carry
     ld a,(data)
     ld hl,(adr)
     call storea
     call negativea
     jp zeroa

lsrm call param16
     ld (adr),hl
     call loada
     srl a
     ld (data),a
     call carry
     ld a,(data)
     ld hl,(adr)
     call storea
     call negativea
     jp zeroa

lsrmx call param16
     call addx16
     ld (adr),hl
     call loada
     srl a
     ld (data),a
     call carry
     ld a,(data)
     ld hl,(adr)
     call storea
     call negativea
     jp zeroa

andk call param8
andc ld b,a
     ld a,(rega)
     and b
     ld (rega),a
     ld (data),a
     call negative
     jp zeroa
andz call param8
     ld h,0:ld l,a
     call loada
     jp andc
andzx call param8
      ld h,0:ld l,a
      call addx8
      call loada
      jp andc
andm call param16
     call loada
     jp andc
andmx call param16
      call addx16
      call loada
      jp andc
andmy call param16
      call addy16
      call loada
      jp andc
andix call param8
      ld h,0:ld l,a
      call addx8
      call paramind
      call loada
      jp andc
andiy call param8
      ld h,0:ld l,a
      call paramind
      call addy16
      call loada
      jp andc

orak call param8
orac ld b,a
     ld a,(rega)
     or b
     ld (rega),a
     ld (data),a
     call negative
     jp zeroa
oraz call param8
     ld h,0:ld l,a
     call loada
     jp orac
orazx call param8
      ld h,0:ld l,a
      call addx8
      call loada
      jp orac
oram call param16
     call loada
     jp orac
oramx call param16
      call addx16
      call loada
      jp orac
oramy call param16
      call addy16
      call loada
      jp orac
oraix call param8
      ld h,0:ld l,a
      call addx8
      call paramind
      call loada
      jp orac
oraiy call param8
      ld h,0:ld l,a
      call paramind
      call addy16
      call loada
      jp orac

eork call param8
eorc ld b,a
     ld a,(rega)
     xor b
     ld (rega),a
     ld (data),a
     call negative
     jp zeroa
eorz call param8
     ld h,0:ld l,a
     call loada
     jp eorc
eorzx call param8
      ld h,0:ld l,a
      call addx8
      call loada
      jp eorc
eorm call param16
     call loada
     jp eorc
eormx call param16
      call addx16
      call loada
      jp eorc
eormy call param16
      call addy16
      call loada
      jp eorc
eorix call param8
      ld h,0:ld l,a
      call addx8
      call paramind
      call loada
      jp eorc
eoriy call param8
      ld h,0:ld l,a
      call paramind
      call addy16
      call loada
      jp eorc

rola  ld a,(rega)
      ld b,a
      call rolb
      ld (rega),a

rolb  call tstc
      jr nz,rolacs
      scf
      ccf
      jp rolac
rolacs scf
rolac  ld a,b
       rla
       ld b,a
       call carry
       ld a,b:ret

rolz call param8
     ld h,0:ld l,a
rolzc ld (adr),hl
     call loada
     ld b,a:call rolb
     ld hl,(adr)
     call storea
     ret

rolzx call param8
      ld h,0:ld l,a
      call addx8
      jp rolzc

rolm call param16
     jp rolzc

rolmx call param16
      call addx16
      jp rolzc

rora  ld a,(rega)
      ld b,a
      call rorb
      ld (rega),a

rorb  call tstc
      jr nz,roracs
      scf
      ccf
      jp rorac
roracs scf
rorac  ld a,b
       rra
       ld b,a
       call carry
       ld a,b:ret

rorz call param8
     ld h,0:ld l,a
rorzc ld (adr),hl
      call loada
     ld b,a:call rorb
     ld hl,(adr)
     call storea
     ret

rorzx call param8
      ld h,0:ld l,a
      call addx8
      jp rorzc

rorm call param16
     jp rorzc

rormx call param16
      call addx16
      jp rorzc

clc jp resc
sec jp setc
cld jp resd
sed jp setd
cli jp resi
sei jp seti
clv jp resv

cmpk call param8
cmpc ld b,a
     ld a,(rega)
cmpr sub b
     ld (data),a
     ccf
     call carry
     call negativea
     jp zeroa

cmpz call param8
     ld h,0:ld l,a
     call loada
     jp cmpc

cmpzx call param8
      ld h,0:ld l,a
      call addx8
      call loada
      jp cmpc

cmpm call param16
     call loada
     jp cmpc
cmpmx call param16
      call addx16
      call loada
      jp cmpc
cmpmy call param16
      call addy16
      call loada
      jp cmpc
cmpix call param8
      ld h,0:ld l,a
      call addx8
      call paramind
      call loada
      jp cmpc
cmpiy call param8
      ld h,0:ld l,a
      call paramind
      call addy16
      call loada
      jp cmpc

cpxk call param8
     ld b,a
     ld a,(regx)
     jp cmpr
cpxz call param8
     ld h,0:ld l,a
     call loada
     ld b,a
     ld a,(regx)
     jp cmpr
cpxm call param16
     call loada
     ld b,a
     ld a,(regx)
     jp cmpr
cpyk call param8
     ld b,a
     ld a,(regy)
     jp cmpr
cpyz call param8
     ld h,0:ld l,a
     call loada
     ld b,a
     ld a,(regy)
     jp cmpr
cpym call param16
     call loada
     ld b,a
     ld a,(regy)
     jp cmpr

bitz call param8
     ld h,0:ld l,a
bitcomm call loada
     ld (data),a
     and %01000000
     jr z,bitcorv
     call setv
bitcov call negativea
     ld a,(rega)
     and (data)
     jp zero
bitcorv call resv:jp bitcov

bitm call param16
     jp bitcomm


 END OF CORE INSTRUCTION SET 


Nsleduj rutiny pro natn parametr za instrukc, rutiny pro zpracovn nepޒmch a indexovanch parametr - piten osmibitovho nebo 16bitovho sla k emulovanmu X nebo Y registru.


param ld hl,(regpc)
      inc hl
      ld (regpc),hl
      ret
param8 call param
       call loada
       ret
param16
     call param
     call loada
     ld (adr),a
     call param
     call loada
     ld (adr+1),a
     ld hl,(adr)
     ret
paramind push hl
         call loada
         ld (adr),a
         pop hl:inc hl
         call loada
         ld (adr+1),a
         ld hl,(adr)
         ret
addx8 ld a,(regx)
      add a,l:ld l,a
      ret
addx16 ld a,(regx)
       ld e,a:ld d,0
       add hl,de:ret
addy8 ld a,(regy)
      add a,l:ld l,a
      ret
addy16 ld a,(regy)
       ld e,a:ld d,0
       add hl,de:ret

Zde je pak prostor, kde jsou uloeny emulovan registry.
Osmibitov stack REGS je rozen na 16bitov registr REGSP.
Je pednastaven registr REGPC a flagy REGP na vchoz hodnoty, ostatn registry jsou nulov.

Potom nsleduj rutiny pro prci s flagy.
ADDR a DATA jsou dv doasn loit 16bitov a 8bitov hodnoty.


 6502 REGISTERS 

rega  nop
regx  nop
regy  nop
regp  db %00100010
regsp
regs  nop
      db 1
regpc dw #ff00

negativea ld a,(data)
negative  and %10000000
          jr z,resn
          jp setn

carry jr c,setc
      jp resc

flow jp po,resv
     jp setv

zeroa ld a,(data)
zero  or a
      jr z,setz
      jp resz

setc ld d,%1
     jp setcom
setz ld d,%10
     jp setcom
seti ld d,%100
     jp setcom
setd ld d,%1000
     jp setcom
setb ld d,%10000
     jp setcom
setv ld d,%1000000
     jp setcom
setn ld d,%10000000
setcom ld a,(regp)
       or d
       ld  (regp),a
       ret
resc ld d,%11111110
     jp rescom
resz ld d,%11111101
     jp rescom
resi ld d,%11111011
     jp rescom
resd ld d,%11110111
     jp rescom
resb ld d,%11101111
     jp rescom
resv ld d,%10111111
     jp rescom
resn ld d,%01111111
rescom ld a,(regp)
       and d
       ld (regp),a
       ret
tstz ld d,%00000010
     jp tstcom
tstn ld d,%10000000
     jp tstcom
tstc ld d,%00000001
     jp tstcom
tstd ld d,%00001000
     jp tstcom
tstv ld d,%01000000
tstcom ld a,(regp)
       and d
       ret

adr nop:nop
data nop

Nsleduje tabulka instrukc.
Jako jedin je zarovnan na 256bajtovou "strnku" a obsahuje prost jen 16bitov adresy rutin pro vykonn instrukc azench vzestupn.
Nedokumentovan instrukce nejsou emulovny, jejich kd je oznaen ILG.


                 
   T A B L E S   
                 

 
          org $/256+1*256

table  dw brk,oraix,ilg,ilg
       dw ilg,oraz,aslz,ilg
       dw php,orak,asla,ilg
       dw ilg,oram,aslm,ilg

       dw bpl,oraiy,ilg,ilg
       dw ilg,orazx,aslzx,ilg
       dw clc,oramy,ilg,ilg
       dw ilg,oramx,aslmx,ilg

       dw jsr,andix,ilg,ilg
       dw bitz,andz,rolz,ilg
       dw plp,andk,rola,ilg
       dw bitm,andm,rolm,ilg

       dw bmi,andiy,ilg,ilg
       dw ilg,andzx,rolzx,ilg
       dw sec,andmy,ilg,ilg
       dw ilg,andmx,rolmx,ilg

       dw rti,eorix,ilg,ilg
       dw ilg,eorz,lsrz,ilg
       dw pha,eork,lsra,ilg
       dw jmpk,eorm,lsrm,ilg

       dw bvc,eoriy,ilg,ilg
       dw ilg,eorzx,lsrzx,ilg
       dw cli,eormy,ilg,ilg
       dw ilg,eormx,lsrmx,ilg

       dw rts,adcix,ilg,ilg
       dw ilg,adcz,rorz,ilg
       dw pla,adck,rora,ilg
       dw jmpm,adcm,rorm,ilg

       dw bvs,adciy,ilg,ilg
       dw ilg,adczx,rorzx,ilg
       dw sei,adcmy,ilg,ilg
       dw ilg,adcmx,rormx,ilg

       dw ilg,staix,ilg,ilg
       dw styz,staz,stxz,ilg
       dw dey,ilg,txa,ilg
       dw stym,stam,stxm,ilg

       dw bcc,staiy,ilg,ilg
       dw styzx,stazx,stxzy,ilg
       dw tya,stamy,txs,ilg
       dw ilg,stamx,ilg,ilg

       dw ldyk,ldaix,ldxk,ilg
       dw ldyz,ldaz,ldxz,ilg
       dw tay,ldak,tax,ilg
       dw ldym,ldam,ldxm,ilg

       dw bcs,ldaiy,ilg,ilg
       dw ldyzx,ldazx,ldxzy,ilg
       dw clv,ldamy,tsx,ilg
       dw ldymx,ldamx,ldxmy,ilg

       dw cpyk,cmpix,ilg,ilg
       dw cpyz,cmpz,decz,ilg
       dw iny,cmpk,dex,ilg
       dw cpym,cmpm,decm,ilg

       dw bne,cmpiy,ilg,ilg
       dw ilg,cmpzx,deczx,ilg
       dw cld,cmpmy,ilg,ilg
       dw ilg,cmpmx,decmx,ilg

       dw cpxk,sbcix,ilg,ilg
       dw cpxz,sbcz,incz,ilg
       dw inx,sbck,noop,ilg
       dw cpxm,sbcm,incm,ilg

       dw beq,sbciy,ilg,ilg
       dw ilg,sbczx,inczx,ilg
       dw sed,sbcmy,ilg,ilg
       dw ilg,sbcmx,incmx,ilg
